#!/usr/bin/perl -w

###############################################################################
# users.pl - this code is for user creation and  administration 
#
# Copyright (C) 1997 Rob "CmdrTaco" Malda
# malda@slashdot.org
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
#
#
#  $Id: users.pl,v 1.1.1.1 2001/02/24 17:52:13 alessio Exp $
###############################################################################
use strict;
use lib '../';
use vars '%I';
use vars '%L';
use Slash;

#################################################################
sub main {
	*I = getSlashConf();
        *L = \%Slash::L;    
	getSlash();

	my $op = $I{F}{op};

	if ($op eq "$L{userlogin}" and $I{U}{uid} > 0) {
		my $refer = $I{F}{returnto} || $I{rootdir};
		redirect($refer);
		return;
	}

	header("$I{sitename} $L{Users}");

	print <<EOT if $I{U}{uid} > 0 && $op ne "userclose";
 [
	<A HREF="$ENV{SCRIPT_NAME}">$L{User_Info}</A> |
	<A HREF="$ENV{SCRIPT_NAME}?op=edituser">$L{Edit_User_Info}</A> |
	<A HREF="$ENV{SCRIPT_NAME}?op=edithome">$L{Customize_Homepage}</A> |
	<A HREF="$ENV{SCRIPT_NAME}?op=editcomm">$L{Customize_Comments}</A> |
	<A HREF="$ENV{SCRIPT_NAME}?op=userclose">$L{Logout}</A>
 ]

EOT

	# and now the carnage begins
	if ($op eq "newuser") {
		newUser();

	} elsif ($op eq "edituser") {
		# the users_prefs table
		if ($I{U}{uid} > 0) {
			editUser($I{U}{nickname});
		} else {
			displayForm(); #crapMesg();
		}

	} elsif ($op eq "edithome" || $op eq "preferences") {
		# also known as the user_index table
		if ($I{U}{uid} > 0) {
			editHome($I{U}{nickname});
		} else {
			displayForm(); #crapMesg();
		}

	} elsif ($op eq "editcomm") {
		# also known as the user_comments table
		if ($I{U}{uid} > 0) {
			editComm($I{U}{nickname});
		} else {
			displayForm(); #crapMesg();
		}

	} elsif ($op eq "userinfo" || !$op) {
		if ($I{F}{nick}) {
			userInfo($I{F}{nick});
		} elsif ($I{U}{uid} < 1) {
			displayForm();
		} else {
			userInfo($I{U}{nickname});
		}

	} elsif ($op eq "$L{saveuser}") {
		saveUser($I{U}{uid});
		userInfo($I{U}{nickname});

	} elsif ($op eq "$L{savecomm}") {
		saveComm($I{U}{uid});
		userInfo($I{U}{nickname});

	} elsif ($op eq "$L{savehome}") {
		saveHome($I{U}{uid});
		userInfo($I{U}{nickname});

	} elsif ($op eq "sendpw") {
		mailPassword($I{U}{nickname});

	} elsif ($op eq "$L{mailpasswd}") {
		mailPassword($I{F}{unickname});

	} elsif ($op eq "suedituser" && $I{U}{aseclev} > 100) {
		editUser($I{F}{name});

	} elsif ($op eq "susaveuser" && $I{U}{aseclev} > 100) {
		saveUser($I{F}{uid}); 

	} elsif ($op eq "sudeluser" && $I{U}{aseclev} > 100) {
		delUser($I{F}{uid});

	} elsif ($op eq "userclose") {
		print "$L{ok_bubbye_now}.";
		displayForm();

	} elsif ($op eq "$L{userlogin}" && $I{U}{uid} > 0) {
		# print $query->redirect("$I{rootdir}/index.pl");
		userInfo($I{U}{nickname});

	} elsif ($op eq "preview") {
		previewSlashbox();

	} elsif ($I{U}{uid} > 0) {
		userInfo($I{F}{nick});

	} else {
		displayForm();
	}

	miniAdminMenu() if $I{U}{aseclev} > 100;
	writelog("users", $I{U}{nickname});
	footer();
}

#################################################################
sub crapMesg {
	print eval prepBlock($L{Oh_Crap_});
}

#################################################################
sub checkList {
	my $string = shift;
	$string = substr($string, 0, -1);

	$string =~ s/[^\w,-]//g;
	my @e = split m/,/, $string;
	$string = sprintf "'%s'", join "','", @e;

	if (length($string) > 254) {
		print "$L{You_selected_too_many_options}";
		$string = substr($string, 0, 255);
		$string =~ s/,'??\w*?$//g;
	} elsif (length $string < 3) {
		$string = "";
	}

	return $string;
}

#################################################################
sub previewSlashbox {
	my ($title, $content, $url) = sqlSelect(
		"title,block,url", "blocks, sectionblocks",
		"section='index' AND blocks.bid = sectionblocks.bid AND blocks.bid = "
		. $I{dbh}->quote($I{F}{bid})
	);

	my $cleantitle = $title;
	$cleantitle =~ s/<(.*?)>//g;

	titlebar("100%","Preview $cleantitle");
	print eval prepBlock($L{What_you_see_on_the_right_hand_side_});
	
	print <<EOT if $I{U}{aseclev} > 999;
<P>Edit <A HREF="$I{rootdir}/admin.pl?op=blocked&bid=$I{F}{bid}">$I{F}{bid}</A>
EOT

	print qq!</TD><TD WIDTH="180" VALIGN="TOP">!;

	print portalbox($I{fancyboxwidth}, $title, $content, "", $url);
}

#################################################################
sub miniAdminMenu {
	print <<EOT;
<FORM ACTION="$ENV{SCRIPT_NAME}">
	<FONT SIZE="${\( $I{fontbase} + 1 )}"> [
		<A HREF="$I{rootdir}/admin.pl">Admin</A> |
		<INPUT TYPE="HIDDEN" NAME="op" VALUE="suedituser">
		<INPUT TYPE="TEXT" NAME="name" VALUE="$I{F}{nick}">
		<INPUT TYPE="SUBMIT" VALUE="Edit">
	</FONT> ]
</FORM>
EOT
}

#################################################################
sub newUser {
	# Check if User Exists

	$I{F}{newuser} =~ s/\s+/ /g;
	$I{F}{newuser} =~ s/[^ a-zA-Z0-9\$_.+!*'(),-]+//g;
	$I{F}{newuser} = substr($I{F}{newuser}, 0, 20);

	(my $matchname = lc $I{F}{newuser}) =~ s/[^a-zA-Z0-9]//g;

	my($cnt) = sqlSelect(
		"matchname","users",
		"matchname=" . $I{dbh}->quote($matchname)
	) || sqlSelect(
		"realemail","users",
		" realemail=" . $I{dbh}->quote($I{F}{email})
	);

	if ($matchname ne '' && $I{F}{newuser} ne '' && !$cnt && $I{F}{email} =~ /\@/) {
		titlebar("100%", eval prepBlock($L{User_newuser_created}));

		$I{F}{pubkey} = stripByMode($I{F}{pubkey}, "html");

		sqlInsert("users", {
			realemail	=> $I{F}{email}, 
			nickname	=> $I{F}{newuser},
			matchname	=> $matchname,
			passwd		=> changePassword()
		});

		my($uid) = sqlSelect("LAST_INSERT_ID()");
		sqlInsert("users_info", { uid => $uid, -lastaccess=>'now()' } );
		sqlInsert("users_prefs", { uid => $uid } );
		sqlInsert("users_comments", { uid => $uid } );
		sqlInsert("users_index", { uid => $uid } );
		# sqlInsert("users_key", { uid => $uid } ); # Not necessary

		print <<EOT;

	<B>email</B>=$I{F}{email}<BR>
	<B>user id</B>=$uid<BR>
	<B>nick</B>=$I{F}{newuser}<BR>
	<B>passwd</B>=mailed to $I{F}{email}<BR>
EOT
	print eval prepBlock($L{Once_you_receive_your_password_});

		mailPassword($I{F}{newuser});

	} else {
		# Duplicate User
		displayForm();
	}
}

#################################################################
sub changePassword {
	my @chars = grep !/[0O1Iil]/, 0..9, 'A'..'Z', 'a'..'z';
	return join '', map { $chars[rand @chars] } 0 .. 7;
}

#################################################################
sub mailPassword {
	my($name) = @_;
	my($nickname, $passwd, $email) = sqlSelect(
		"nickname,passwd,realemail", "users",
		"nickname=" . $I{dbh}->quote($name)
	);

	my $msg = blockCache("newusermsg");
	$msg = prepBlock($msg);
	$msg = eval $msg;

	if ($name ne '' && (lc($name) eq lc($nickname))) {
		sendEmail($email, eval prepBlock($L{user_password_for_name}), $msg) if $name;
		print eval prepBlock($L{Passwd_just_emailed});
	} else {
		print eval prepBlock($L{name_not_found_no_password_mailed});
	}
}

#################################################################
sub userInfo {
	my($nick) = @_;

	my $c = $I{dbh}->prepare(
		"SELECT homepage,fakeemail,users.uid,bio, seclev,karma
		 FROM users, users_info
		 WHERE users.uid = users_info.uid AND nickname="
		. $I{dbh}->quote($nick) . " and users.uid > 0"
	);
	$c->execute;

	if (my($home, $email, $uid, $bio, $useclev, $karma) = $c->fetchrow) {
		$bio = stripByMode($bio, "html");
		if ($I{U}{nickname} eq $nick) {
			my $sth = $I{dbh}->prepare("SELECT points FROM users_comments WHERE uid=$uid");
			$sth->execute;
			my $points = $sth->fetchrow_array;
			$sth->finish;

			titlebar("95%", eval prepBlock($L{Welcome_back_nick_}));
			print eval prepBlock($L{This_is_your_User_Info_page_});
			if ($I{U}{uid} == $uid && $points > 0) {
				print eval prepBlock($L{Youre_a_moderator_with_points_});
			}
			print <<EOT;
<CENTER><IMG SRC="$I{imagedir}/greendot.gif" WIDTH="75%" HEIGHT="1" ALIGN="CENTER"><BR></CENTER>
EOT

		} else {
			titlebar("95%", "$L{User_Info_for} $nick ($uid)");
		}

		print qq!<A HREF="$home">$home</A><BR><A HREF="mailto:$email">$email</A><BR>!;
		print eval prepBlock($L{Karma_karma_})
			if $I{U}{aseclev} || $I{U}{uid} == $uid;
		print eval prepBlock($L{User_Bio_}) if $bio;

		my($k) = sqlSelect("pubkey", "users_key", "uid=$uid");
		$k = stripByMode($k, "html");
		print "<B>$L{Public_Key}</B><BR><PRE>\n$k</PRE><P>" if $k;

		$I{F}{min} = 0 unless $I{F}{min};

		my $sqlquery = "SELECT pid,sid,cid,subject,"
#			. getDateFormat("date","d")
			. "date"
			. ",points FROM comments WHERE uid=$uid ";
		$sqlquery .= " ORDER BY date DESC LIMIT $I{F}{min},50 ";

		my $comments = $I{dbh}->prepare($sqlquery);
		$comments->execute;
		my $commentsRows = $comments->rows;
		print eval prepBlock($L{nick_has_posted_comments_});

		my $x;
		while (my($pid, $sid, $cid, $subj, $cdate, $pts) = $comments->fetchrow) {
			$cdate = timeCalc($cdate);
			$x++;
			my($r) = sqlSelect("count(*)", "comments", "sid='$sid' and pid=$cid");
			my $replies = " $L{Replies}:$r" if $r;

			print <<EOT;
<BR><B>$x</B> <A HREF="$I{rootdir}/comments.pl?sid=$sid&cid=$cid">$subj</A> $L{'posted on'} $cdate ($L{Score}:$pts$replies)
<FONT SIZE="${\( $I{fontbase} + 2 )}">
EOT
			my $S = sqlSelectHashref("section, title, writestatus", "stories", "sid='$sid'");

			if ($S) {
				my $href = $S->{writestatus} == 10
					? "$I{rootdir}/$S->{section}/$sid.shtml"
					: "$I{rootdir}/article.pl?sid=$sid";

				print qq!<BR>$L{attached_to} <A HREF="$href">$S->{title}</A>!;
# $S->{section}/$sid.shtml
			} else {
				my $P = sqlSelectHashref("question", "pollquestions", "qid='$sid'");
				print qq!<BR>$L{attached_to} <A HREF="$I{rootdir}/pollBooth.pl?qid=$sid"> $P->{question}</A>!
					if $P->{question};
			}
			print "</FONT>";
		}

		$comments->finish;

	} else {
		print "$nick not found.";
	}

	$c->finish;
}

#################################################################
sub editKey {
	my($k) = sqlSelect("pubkey", "users_key", "uid=$_[0]");
	printf qq!<P><B>$L{Public_Key}</B><BR><TEXTAREA NAME="pubkey" ROWS="4" COLS="60">%s</TEXTAREA>!,
		stripByMode($k, 'literal');
}

#################################################################
sub editUser {
	my($name) = @_;
	my($uid, $realname, $realemail, $fakeemail, $homepage, $nickname,
		$passwd, $sig, $useclev, $bio, $maillist) = sqlSelect(
		"users.uid, realname, realemail, fakeemail, homepage, nickname, " .
		"passwd, sig, seclev, bio, maillist", "users, users_info",
		"users.uid=users_info.uid AND nickname=" . $I{dbh}->quote($name)
	); 

	return if $uid < 1;

	titlebar("100%", "$L{Editing} $name ($uid) $realemail");
	print qq!<TABLE ALIGN="CENTER" WIDTH="95%" BGCOLOR="$I{bg}[2]"><TR><TD>!;

	$homepage ||= "http://";
 
	my $tempnick = $nickname;
	$tempnick =~ s/ /+/g;

 	print eval prepBlock($L{You_can_automatically_login_});
	print <<EOT;

<FORM ACTION="$ENV{SCRIPT_NAME}" METHOD="POST">

	$L{Real_Name_}
		<INPUT TYPE="TEXT" NAME="realname" VALUE="$realname" SIZE="40"><BR>
		<INPUT TYPE="HIDDEN" NAME="uid" VALUE="$uid">
		<INPUT TYPE="HIDDEN" NAME="passwd" VALUE="$passwd">
		<INPUT TYPE="HIDDEN" NAME="name" VALUE="$nickname">

	$L{Real_Email_}
		<INPUT TYPE="TEXT" NAME="realemail" VALUE="$realemail" SIZE="40"><BR>

	$L{Fake_Email_}
		<INPUT TYPE="TEXT" NAME="fakeemail" VALUE="$fakeemail" SIZE="40"><BR>

	$L{Homepage_}
		<INPUT TYPE="TEXT" NAME="homepage" VALUE="$homepage" SIZE="60"><BR>

	<P><B>$L{Headline_Mailing_List}</B>
EOT

	selectForm("maillist", "maillist", $maillist);
	printf <<EOT, stripByMode($sig, 'literal'), stripByMode($bio, 'literal');
	$L{Sig_}
		<TEXTAREA NAME="sig" ROWS="2" COLS="60">%s</TEXTAREA>

	$L{Bio_}
		<TEXTAREA NAME="bio" ROWS="5" COLS="60" WRAP="virtual">%s</TEXTAREA>

EOT

	editKey($uid);

  	print <<EOT;
	$L{Password_}
		<INPUT TYPE="PASSWORD" NAME="pass1" SIZE="12" MAXLENGTH="12">
		<INPUT TYPE="PASSWORD" NAME="pass2" SIZE="12" MAXLENGTH="12"><P>

</TD></TR></TABLE><P>

	<INPUT TYPE="SUBMIT" NAME="op" VALUE="$L{saveuser}">
	</FORM>
EOT

	# print "	<INPUT TYPE="SUBMIT" NAME="op" VALUE="susaveuser"> <INPUT TYPE="SUBMIT" NAME="op" VALUE="sudeluser">" if $I{U}{aseclev}> 499;
}

#################################################################
sub tildeEd {
	my($extid, $exsect, $exaid, $exboxes, $userspace) = @_;
	
	titlebar("100%", "$L{Exclude_Stories_Homepage}");

	print <<EOT;
<TABLE WIDTH="95%" BORDER="0" CELLPADDING="3" CELLSPACING="3" ALIGN="CENTER">
		<TR BGCOLOR="$I{bg}[3]">
			<TH><FONT COLOR="$I{fg}[3]" SIZE="${\( $I{fontbase} + 4 )}">$L{Authors}</FONT></TH>
			<TH><FONT COLOR="$I{fg}[3]" SIZE="${\( $I{fontbase} + 4 )}">$L{Topics}</FONT></TH>
			<TH><FONT COLOR="$I{fg}[3]" SIZE="${\( $I{fontbase} + 4 )}">$L{Sections}</FONT></TH>
		</TR><TR BGCOLOR="$I{bg}[2]"><TD VALIGN="TOP">
EOT

	# Customizable Authors Thingee
	my $C = sqlSelectMany("aid", "authors", "seclev > 99", "order by aid");
	while (my($aid) = $C->fetchrow) {
		my $checked = ($exaid =~ /'$aid'/) ? ' CHECKED' : '';
		print qq!<INPUT TYPE="CHECKBOX" NAME="exaid_$aid"$checked>$aid<BR>\n!;
	}

	$C->finish;

	# Customizable Topic
	print qq!</TD><TD VALIGN="TOP"><MULTICOL COLS="3">!;
	$C = sqlSelectMany("tid,alttext", "topics", "1=1 ", "order by tid");
	while (my($tid, $alttext) = $C->fetchrow) {
		my $checked = ($extid =~ /'$tid'/) ? ' CHECKED' : '';
		print qq!<INPUT TYPE="CHECKBOX" NAME="extid_$tid"$checked>$alttext<BR>\n! if $tid;
	}

	$C->finish;
	print "</MULTICOL></TD>";

	# Customizable Sections
	print '<TD VALIGN="TOP">';
	$C = sqlSelectMany("section,title", "sections", "isolate=0", "order by title");

	while (my($section,$title) = $C->fetchrow) {
		my $checked = ($exsect =~ /'$section'/) ? " CHECKED" : "";
		print qq!<INPUT TYPE="CHECKBOX" NAME="exsect_$section"$checked>$title<BR>\n! if $section;
	}

	$C->finish;
	print "</TD>";

	print "</TD></TR></TABLE><P>";
	
	titlebar("100%", "$L{Customize_Slashboxes}");

	$userspace = stripByMode($userspace, 'literal');
	print <<EOT;
<TABLE WIDTH="95%" BGCOLOR="$I{bg}[2]" ALIGN="CENTER" BORDER="0">
	<TR><TD>
	$L{Look_ma_Im_configurable_}
EOT
	
	print eval prepBlock($L{User_Space_});
	print <<EOT;
		<TEXTAREA NAME="mylinks" rows=5 COLS="60" WRAP="VIRTUAL">$userspace</TEXTAREA>

	<P><MULTICOL COLS="3">
EOT

	$C = sqlSelectMany("bid,title,ordernum", "sectionblocks", "section='index' AND portal=1", "order by bid");

	while (my($bid,$title,$o) = $C->fetchrow) {
		my $checked = ($exboxes =~ /'$bid'/) ? " CHECKED" : "";
		$title =~ s/<(.*?)>//g;
		print "<B>" if $o > 0;
		print qq!<INPUT TYPE="CHECKBOX" NAME="exboxes_$bid"$checked>!
			. qq!<A HREF="$ENV{SCRIPT_NAME}?op=preview&bid=$bid">!;

		unless ($bid eq "srandblock") {
			print $title;
		} else {
			print "Semi-Random Box";
		}

		print "</A><BR>\n";
		print "</B>" if $o > 0;
	}

	$C->finish;

	print "</MULTICOL><P>";
	print eval prepBlock($L{If_you_have_reasonable_suggestions_});
	print "<P></TD></TR></TABLE>";
}

#################################################################
sub editHome {
	my($name) = @_;

	my($uid, $willing, $tzformat, $tzcode, $noicons, $light, $userspace,
		$extid, $exaid, $exsect, $exboxes, $maxstories, $noboxes)
		= sqlSelect("users.uid, willing, dfid, tzcode, noicons, light, "
		. "mylinks, users_index.extid, users_index.exaid, "
		. "users_index.exsect, users_index.exboxes, users_index.maxstories, "
		. "users_index.noboxes", "users, users_prefs, users_index",
		"users.uid=users_prefs.uid AND users.uid=users_index.uid AND "
		. "users.nickname=" . $I{dbh}->quote($name)
	);

	return if $uid < 1;

	titlebar("100%", eval prepBlock($L{Customize_sitename_Display}));

	print <<EOT;
	<FORM ACTION="$ENV{SCRIPT_NAME}" METHOD="POST">
	<TABLE ALIGN="CENTER" WIDTH="95%" BGCOLOR="$I{bg}[2]"><TR><TD>

		<B>$L{Date_Time_Format}</B><NOBR>
EOT

	selectGeneric("dateformats", "tzformat", "id", "description", $tzformat);
	selectGeneric("tzcodes", "tzcode", "tz", "description", $tzcode);
	print "</NOBR>";

	my $l_check = $light	? " CHECKED" : "";
	my $b_check = $noboxes	? " CHECKED" : "";
	my $i_check = $noicons	? " CHECKED" : "";
	my $w_check = $willing	? " CHECKED" : "";

	print qq!<P><INPUT TYPE="CHECKBOX" NAME="light"$l_check>!;
	print eval prepBlock($L{Light_});

	print <<EOT;

	<P><INPUT TYPE="CHECKBOX" NAME="noboxes"$b_check>
	$L{Deactivate_Slashboxes}

	<P><INPUT TYPE="CHECKBOX" NAME="noicons"$i_check>
	$L{No_Icons}

	$L{Maximum_Stories}
	<INPUT TYPE="TEXT" NAME="maxstories" SIZE="3" VALUE="$maxstories">

	<P><INPUT TYPE="CHECKBOX" NAME="willing"$w_check>
EOT

	print eval prepBlock($L{Willing_to_Moderate});

	print <<EOT;

	</TD></TR></TABLE><P>
EOT

	tildeEd($extid, $exsect, $exaid, $exboxes, $userspace);

	print qq!\t<INPUT TYPE="SUBMIT" NAME="op" VALUE="$L{savehome}">\n!;
	# print qq!\t<INPUT TYPE="SUBMIT" NAME="op" VALUE="susaveuser"> <INPUT TYPE="SUBMIT" NAME="op" VALUE="sudeluser">! if $I{U}{aseclev}> 499;
	print "\t</FORM>\n\n";
}

#################################################################
sub editComm {
	my($name) = @_;

	my($uid, $points, $posttype, $defaultpoints, $maxcommentsize,
		$clsmall, $clbig, $reparent, $noscores, $highlightthresh,
		$commentlimit, $nosigs, $commentspill, $commentsort, $mode,
		$threshold, $hardthresh)
		= sqlSelect("users.uid, points, posttype, defaultpoints, "
		. "maxcommentsize, clsmall, clbig, reparent, noscores, "
		. "highlightthresh, commentlimit, nosigs, commentspill, "
		. "commentsort, mode, threshold, hardthresh",
		"users, users_comments","users.uid=users_comments.uid AND nickname="
		. $I{dbh}->quote($name)
	);

	titlebar("100%", "$L{Comment_Options}");

	print <<EOT;
	<FORM ACTION="$ENV{SCRIPT_NAME}" METHOD="POST">
	<TABLE ALIGN="CENTER" WIDTH="95%" BGCOLOR="$I{bg}[2]"><TR><TD>
EOT

	print "<B>$L{Display_Mode}</B>";
	selectGeneric("commentmodes", "umode", "mode", "name", $mode);

	print "$L{Sort_Order}\n";
	selectForm("sortcodes", "commentsort", $commentsort);

	print "<P><B>$L{Threshold}</B>";
	selectGeneric("threshcodes", "uthreshold", "thresh", "description", $threshold);

	print eval prepBlock($L{comments_scored_less_than_});

	print "<P><B>$L{Highlight_Threshold}</B>";
	selectGeneric("threshcodes", "highlightthresh", "thresh", "description", $highlightthresh);

	print " <BR>($L{comments_scoring_this_})";

	my $h_check = $hardthresh	? " CHECKED" : "";
	my $r_check = $reparent		? " CHECKED" : "";
	my $n_check = $noscores		? " CHECKED" : "";
	my $s_check = $nosigs		? " CHECKED" : "";

	print <<EOT;
	
	$L{Hard_Thresholds_}
	<INPUT TYPE="CHECKBOX" NAME="hardthresh"$h_check>

	$L{Reparent_Highly_Rated_Comments_}
	<INPUT TYPE="CHECKBOX" NAME="reparent"$r_check>

	$L{Do_Not_Display_Scores_}
	<INPUT TYPE="CHECKBOX" NAME="noscores"$n_check>
	
	$L{Limit_only_display_}
	<INPUT TYPE="TEXT" NAME="commentlimit" SIZE="6" VALUE="$commentlimit">

	$L{Index_Spill_}
	<INPUT TYPE="TEXT" NAME="commentspill" VALUE="$commentspill" SIZE="3">

	$L{Small_Comment_Penalty_}
	<INPUT TYPE="TEXT" NAME="clsmall" VALUE="$clsmall" SIZE="6">

	$L{Long_Comment_Bonus_}
	<INPUT TYPE="TEXT" NAME="clbig" VALUE="$clbig" SIZE="6">

	$L{Max_Comment_Size_}
	<INPUT TYPE="TEXT" NAME="maxcommentsize" SIZE="6" VALUE="$maxcommentsize">

	$L{Disable_Sigs_}
	<INPUT TYPE="CHECKBOX" NAME="nosigs"$s_check>

	$L{Comment_Post_Mode}
EOT

	selectGeneric("postmodes", "posttype", "code", "name", $posttype);

	print <<EOT;

	</TD></TR></TABLE><P>

	<INPUT TYPE="SUBMIT" NAME="op" VALUE="$L{savecomm}">
</FORM>
EOT

	# print qq! <INPUT TYPE="SUBMIT" NAME="op" VALUE="susaveuser"> <INPUT TYPE="SUBMIT" NAME="op" VALUE="sudeluser">! if $I{U}{aseclev}> 499;
}

#################################################################
sub saveUser {
	my $uid = $I{U}{aseclev} ? shift : $I{U}{uid};
	my $name = $I{U}{aseclev} && $I{F}{name} ? $I{F}{name} : $I{U}{nickname};

	$name = substr($name, 0, 20);
	return unless $uid > 0;

	print eval prepBlock($L{Saving_Name});
	print <<EOT if $uid < 1 || !$name;
<P>Your browser didn't save a cookie properly.  This could mean you are behind a filter that
eliminates them, you are using a browser that doesn't support them, or you rejected it.
EOT

	# stripByMode _after_ fitting sig into schema, 120 chars
	$I{F}{sig}	 = stripByMode(substr($I{F}{sig}, 0, 120), 'html');
	$I{F}{fakeemail} = chopEntity(stripByMode($I{F}{fakeemail}, 'attribute'), 50);
	$I{F}{homepage}	 = "" if $I{F}{homepage} eq "http://";
	$I{F}{homepage}	 = fixurl($I{F}{homepage});

	# for the users table
	my $H = {
		sig		=> $I{F}{sig},
		homepage	=> $I{F}{homepage},
		fakeemail	=> $I{F}{fakeemail}
	};

	# for the users_info table
	my $H2 = {
		maillist	=> $I{F}{maillist},
		realname	=> $I{F}{realname},
		bio		=> $I{F}{bio}
	};

	my($oldEmail) = sqlSelect("realemail", "users",
		"nickname=" . $I{dbh}->quote($name));

	if ($oldEmail ne $I{F}{realemail}) {
		$H->{realemail} = chopEntity(stripByMode($I{F}{realemail}, 'attribute'), 50);
		print "\nNotifying $oldEmail of the change to their account.<BR>\n";

		sendEmail($oldEmail, "$I{sitename} user email change for $name", <<EOT);
The user account $name on $I{sitename} had this email
associated with it.  A web user from $ENV{REMOTE_ADDR} has
just changed it to $I{F}{realemail}.

If this is wrong, well then we have a problem.	MOST LIKELY THIS IS NO
BIG DEAL.  It probably means you have a common nickname and someone else
wanted it.  They do not have your password, they are not going to sneak
up on you late at night and steal your children.  Only this email address
got this email.	 So do not sweat it unless your account suddenly dies
or something.
EOT
	}

	if ($I{F}{pass1} eq $I{F}{pass2} && length($I{F}{pass1}) > 5) {
		$H->{passwd} = $I{F}{pass1};
		print qq!Password Changed  (You'll need to <A HREF="$ENV{SCRIPT_NAME}">log back in</A> now.)<BR>!;

	} elsif ($I{F}{pass1} ne $I{F}{pass2}) {
		print "Passwords don't match. Password not changed.<BR>";

	} elsif (length $I{F}{pass1} < 6 && $I{F}{pass1}) {
		print "Password is too short and was not changed.<BR>";
	}

	# update the public key
	sqlReplace("users_key", { uid => $uid, pubkey => $I{F}{pubkey} } );

	# Update users with the $H thing we've been playing with for this whole damn sub
	sqlUpdate("users", $H, "uid=" . $uid . " AND uid>0", 1);

	# Update users with the $H thing we've been playing with for this whole damn sub
	sqlUpdate("users_info", $H2, "uid=" . $uid . " AND uid>0", 1);
}

#################################################################
sub saveComm {
	my $uid  = $I{U}{aseclev} ? shift : $I{U}{uid};
	my $name = $I{U}{aseclev} && $I{F}{name} ? $I{F}{name} : $I{U}{nickname};

	$name = substr($name, 0, 20);
	return unless $uid > 0;

	print eval prepBlock($L{Saving_Name});
	print <<EOT if $uid < 1 || !$name;
<P>Your browser didn't save a cookie properly. This could mean you are behind a filter that
eliminates them, you are using a browser that doesn't support them, or you rejected it.
EOT

	# Take care of the lists
	# Enforce Ranges for variables that need it
	$I{F}{commentlimit} = 0 if $I{F}{commentlimit} < 1;
	$I{F}{commentspill} = 0 if $I{F}{commentspill} < 1;

	# for users_comments
	my $H = {
		clbig		=> $I{F}{clbig},
		clsmall		=> $I{F}{clsmall},
		mode		=> $I{F}{umode},
		posttype	=> $I{F}{posttype},
		commentsort	=> $I{F}{commentsort},
		threshold	=> $I{F}{uthreshold},
		commentlimit	=> $I{F}{commentlimit},
		commentspill	=> $I{F}{commentspill},
		maxcommentsize	=> $I{F}{maxcommentsize},
		highlightthresh	=> $I{F}{highlightthresh},
		nosigs		=> ($I{F}{nosigs}     ? "1" : "0"),
		reparent	=> ($I{F}{reparent}   ? "1" : "0"),
		noscores	=> ($I{F}{noscores}   ? "1" : "0"),
		hardthresh	=> ($I{F}{hardthresh} ? "1" : "0"),
	};

	# Update users with the $H thing we've been playing with for this whole damn sub
	sqlUpdate("users_comments", $H, "uid=" . $uid . " AND uid>0", 1);
}

#################################################################
sub saveHome {
	my $uid  = $I{U}{aseclev} ? shift : $I{U}{uid};
	my $name = $I{U}{aseclev} && $I{F}{name} ? $I{F}{name} : $I{U}{nickname};

	$name = substr($name, 0, 20);
	return unless $uid > 0;

	print eval prepBlock($L{Saving_Name});
	print eval prepBlock($L{Your_browser_didnt_save_cookie_}) if $uid < 1 || !$name;

	my($extid, $exaid, $exsect) = "";
	my($exboxes) = sqlSelect("exboxes", "users_index", "uid=$uid");

	$exboxes =~ s/'//g;
	my @b = split m/,/, $exboxes;

	foreach (@b) {
		$_ = "" unless $I{F}{"exboxes_$_"};
	}

	$exboxes = sprintf "'%s',", join "','", @b;
	$exboxes =~ s/'',//g;

	foreach my $k (keys %{$I{F}}) {
		if ($k =~ /^extid_(.*)/)	{ $extid  .= "'$1'," }
		if ($k =~ /^exaid_(.*)/)	{ $exaid  .= "'$1'," }
		if ($k =~ /^exsect_(.*)/)	{ $exsect .="'$1',"  }
		if ($k =~ /^exboxes_(.*)/) { 
			# Only Append a box if it doesn't exist
			my $box = $1;
			$exboxes .= "'$box'," unless $exboxes =~ /'$box'/;
		}
	}

	$I{F}{maxstories} = 66 if $I{F}{maxstories} > 66;
	$I{F}{maxstories} = 1 if $I{F}{maxstories} < 1;

	# Take care of the preferences table

	# for users_index
	my $H = {
		extid		=> checkList($extid),
		exaid		=> checkList($exaid),
		exsect		=> checkList($exsect),
		exboxes		=> checkList($exboxes),
		maxstories	=> $I{F}{maxstories},
		noboxes		=> ($I{F}{noboxes} ? "1" : "0"),
	};

	# for users_prefs
	my $H2 = {
		light		=> ($I{F}{light} ? "1" : "0"),
		noicons		=> ($I{F}{noicons} ? "1" : "0"),
		willing		=> ($I{F}{willing} ? "1" : "0"),
	}; 

	
	if (defined $I{F}{tzcode} && defined $I{F}{tzformat}) {
		$H2->{tzcode} = $I{F}{tzcode};
		$H2->{dfid} = $I{F}{tzformat};
	}

	$H2->{mylinks} = $I{F}{mylinks} if $I{F}{mylinks};

	# If a user is unwilling to moderate, we should cancel all points, lest
	# they be preserved when they shouldn't be.
	sqlUpdate("users_comments", { points => 0 }, "uid=$uid AND uid>0", 1)
		unless $I{F}{willing};

	# Update users with the $H thing we've been playing with for this whole damn sub
	sqlUpdate("users_index", $H, "uid=" . $uid . " AND uid>0", 1);

	# Update users with the $H thing we've been playing with for this whole damn sub
	sqlUpdate("users_prefs", $H2, "uid=" . $uid . " AND uid>0", 1);
}

#################################################################
sub displayForm {
	print <<EOT;
<TABLE WIDTH="100%" CELLPADDING="10"><TR><TD WIDTH="50%" VALIGN="TOP">

<P><FORM ACTION="$ENV{SCRIPT_NAME}" METHOD="POST">

EOT

	titlebar("100%", $I{F}{unickname} ? "$L{Error_Logging_In}" : "$L{Login}");

	print $I{F}{unickname} ? <<EOT1 : $I{allow_anonymous} ? <<EOT2 : <<EOT3;
	$L{Danger_Will_Robinson_}
EOT1
	$L{Logging_in_will_allow_you_} $I{anon_name}.
EOT2
	$L{Logging_in_will_allow_you_2_}
EOT3

	$I{F}{unickname} ||= $I{F}{newuser};

	print <<EOT;

	$L{Nick_maximum_characters_}
	<INPUT TYPE="TEXT" NAME="unickname" SIZE="20" VALUE="$I{F}{unickname}"><BR>

	$L{Password_characters_long_}
	<INPUT TYPE="PASSWORD" NAME="upasswd" SIZE="12" MAXLENGTH="12"><BR>

	<INPUT TYPE="SUBMIT" NAME="op" VALUE="$L{userlogin}">
	<INPUT TYPE="SUBMIT" NAME="op" VALUE="$L{mailpasswd}">

	</TD><TD WIDTH="50%" VALIGN="TOP">
EOT

	titlebar("100%", $I{F}{newuser} ? "$L{Duplicate_Account}" : "$L{Im_a_New_User}");
	print $I{F}{newuser} ? <<EOT1 : <<EOT2;
	$L{Apparently_you_tried_to_register_}
EOT1
	$L{What_You_dont_have_an_account_yet_}
EOT2

	print eval prepBlock($L{Note_only_the_characters_allowed_});
}

main();
$I{dbh}->disconnect if $I{dbh};
1;